Cold Plasma Dispersion Relation

M. E. Mauel
Columbia University
September 29, 2005

Introduction

In this notebook, we define some simple functions that make easy the graphical presentation of the cold plasma dispersion relation in an uniform, magnetized plasma.

Definitions

Off[General::spell1];

ionMassRatio = 1836.2 (* proton to electron mass *);

Ωci = - Ωce/ionMassRatio

Ωpi = Ωpe/Sqrt[ionMassRatio]

Right, Left, Parallel Hand Dielectric Functions (R, L, P)

right = 1 - (1/ω) (((Ωpe)^2)/(ω - Ωce) (* electron *) + ((Ωpi)^2)/(ω + Ωci))

left = 1 - (1/ω) (((Ωpe)^2)/(ω + Ωce) (* electron *) + ((Ωpi)^2)/(ω - Ωci))

para = 1 - ((Ωpe)^2)/(ω^2) - ((Ωpi)^2)/(ω^2)

Gryotropic Dielectric Functions (S, D)

s = (right + left)/2

d = (right - left)/2

Dispersion Relation

disp[n_, θ_, ω_] = (s ((Sin[θ])^2) + para ((Cos[θ])^2)) (n^4) - (right left ((Sin[θ])^2) + para s (1 + ((Cos[θ])^2))) (n^2) + right left para

nIndex[θ_,ω_] = Simplify[((right left ((Sin[θ])^2) + para s (1 + ((Cos[θ])^2))) + {1, -1} Sqrt[(((right left - para s))^2) ((Sin[θ])^4) + 4 (para^2) (d^2) ((Cos[θ])^2)])/(2 (s ((Sin[θ])^2) + para ((Cos[θ])^2))) ]

Simple Limits

High frequency electromagnetic waves…

Series[nIndex[0 Degree, ω], {ω, ∞, 2}] // Chop

Low frequency Alfvén waves…

Series[(((ω/c))^2) nIndex[0 Degree, ω], {ω, 0, 1}] // Chop

Propagation Parallel to B

freqRule = { Ωpe -> 0.5, Ωce -> 1}

Ωce/ionMassRatio /. freqRule (* ion cyclotron frequency *)

Ωpe/Sqrt[ionMassRatio]/. freqRule (* ion plasma frequency *)

Print[freqRule];Plot[Evaluate[nIndex[0.0,w] /. freqRule], {w, 0, 2.5}, PlotStyle -> {{Red}, {Blue}}, PlotRange -> {-5, 5}, AxesLabel -> {"ω", "(n^2)"}];

Print[freqRule];Plot[Evaluate[nIndex[0.0,w] /. freqRule], {w, 0, 3/ionMassRatio}, PlotStyle -> {{Red}, {Blue}}, PlotRange -> {-1000, 5000}, AxesLabel -> {"ω", "(n^2)"}]

freqRule = { Ωpe -> 2, Ωce -> 1}

Ωce/ionMassRatio /. freqRule (* ion cyclotron frequency *)

Ωpe/Sqrt[ionMassRatio]/. freqRule (* ion plasma frequency *)

Print[freqRule];Plot[Evaluate[nIndex[0.0,w] /. freqRule], {w, 0, 2.5}, PlotStyle -> {{Red}, {Blue}}, PlotRange -> {-50, 50}, AxesLabel -> {"ω", "(n^2)"}]

Print[freqRule];Plot[Evaluate[nIndex[0.0,w] /. freqRule], {w, 0, 2.5}, PlotStyle -> {{Red}, {Blue}}, PlotRange -> {-5, 5}, AxesLabel -> {"ω", "(n^2)"}]

Print[freqRule];Plot[Evaluate[nIndex[0.0,w] /. freqRule], {w, 0, 3/ionMassRatio}, PlotStyle -> {{Red}, {Blue}}, PlotRange -> {-50000, 100000}, AxesLabel -> {"ω", "(n^2)"}]

Propagation Perpendicular to B

freqRule = { Ωpe -> 0.5, Ωce -> 1}

Ωce/ionMassRatio /. freqRule (* ion cyclotron frequency *)

Ωpe/Sqrt[ionMassRatio]/. freqRule (* ion plasma frequency *)

Print[freqRule];Plot[Evaluate[nIndex[90.0 Degree,w] /. freqRule], {w, 0, 2.5}, PlotStyle -> {{Red}, {Blue}}, PlotRange -> {-5, 5}, AxesLabel -> {"ω", "(n^2)"}]

freqRule = { Ωpe -> 2, Ωce -> 1}

Ωce/ionMassRatio /. freqRule (* ion cyclotron frequency *)

Ωpe/Sqrt[ionMassRatio]/. freqRule (* ion plasma frequency *)

Print[freqRule];Plot[Evaluate[nIndex[90.0 Degree,w] /. freqRule], {w, 0, 2.5}, PlotStyle -> {{Red}, {Blue}}, PlotRange -> {-5, 5}, AxesLabel -> {"ω", "(n^2)"}]

Propagation at Any Angle

Low-Density

freqRule = { Ωpe -> 0.5, Ωce -> 1}

Ωce/ionMassRatio /. freqRule (* ion cyclotron frequency *)

Ωpe/Sqrt[ionMassRatio]/. freqRule (* ion plasma frequency *)

wRule = w -> 2 Ωce;Print["ω = ",N[w /. wRule /. freqRule]];
Print["X = ",N[(Ωpe/w)^2 /. wRule/. freqRule], " Y = ",N[(Ωce/w) /. wRule/. freqRule]];
Print[freqRule];PolarPlot[Evaluate[Re[Sqrt[nIndex[θ + 90 Degree,w]]] /. wRule /. freqRule ], {θ, 0, 2π}, AspectRatio -> Automatic]

wRule = w -> 0.75 Ωce;Print["ω = ",N[w /. wRule /. freqRule]];
Print["X = ",N[(Ωpe/w)^2 /. wRule/. freqRule], " Y = ",N[(Ωce/w) /. wRule/. freqRule]];
Print[freqRule];PolarPlot[Evaluate[Re[Sqrt[nIndex[θ + 90 Degree,w]]] /. wRule /. freqRule ], {θ, 0, 2π}, AspectRatio -> Automatic]

wRule = w -> 0.1 Ωce;Print["ω = ",N[w /. wRule /. freqRule]];
Print["X = ",N[(Ωpe/w)^2 /. wRule/. freqRule], " Y = ",N[(Ωce/w) /. wRule/. freqRule]];
Print[freqRule];PolarPlot[Evaluate[Re[Sqrt[nIndex[θ + 90 Degree,w]]] /. wRule /. freqRule ], {θ, 0, 2π}, AspectRatio -> Automatic]

High-Density

freqRule = { Ωpe -> 5.0, Ωce -> 1.0}

Ωce/ionMassRatio /. freqRule (* ion cyclotron frequency *)

Ωpe/Sqrt[ionMassRatio]/. freqRule (* ion plasma frequency *)

wRule = w -> 2 Ωce;Print["ω = ",N[w /. wRule /. freqRule]];
Print["X = ",N[(Ωpe/w)^2 /. wRule/. freqRule], " Y = ",N[(Ωce/w) /. wRule/. freqRule]];
Print[freqRule];PolarPlot[Evaluate[Im[Sqrt[nIndex[θ + 90 Degree,w]]] /. wRule /. freqRule ], {θ, 0, 2π}, AspectRatio -> Automatic]

wRule = w -> 0.75 Ωce;Print["ω = ",N[w /. wRule /. freqRule]];
Print["X = ",N[(Ωpe/w)^2 /. wRule/. freqRule], " Y = ",N[(Ωce/w) /. wRule/. freqRule]];
Print[freqRule];PolarPlot[Evaluate[Re[Sqrt[nIndex[θ + 90 Degree,w]]] /. wRule /. freqRule ], {θ, 0, 2π}]

wRule = w -> 0.1 Ωce;Print["ω = ",N[w /. wRule /. freqRule]];
Print["X = ",N[(Ωpe/w)^2 /. wRule/. freqRule], " Y = ",N[(Ωce/w) /. wRule/. freqRule]];
Print[freqRule];PolarPlot[Evaluate[Re[Sqrt[nIndex[θ + 90 Degree,w]]] /. wRule /. freqRule ], {θ, 0, 2π}, AspectRatio -> Automatic]

Polarization

dMatrix = {{s - (n^2)((Cos[θ])^2),  -I d, (n^2)Sin[θ] Cos[θ]}, { I d, s - (n^2), 0}, { (n^2)Sin[θ] Cos[θ], 0, para - (n^2) ((Sin[θ])^2)}}

Example 1

freqRule = { Ωpe -> 0.5, Ωce -> 1}

exampleRule = { ω -> 3 Ωce , θ -> 90 Degree}

(dMatrix /.exampleRule /. freqRule ) // MatrixForm

Det[(dMatrix /.exampleRule /. freqRule )]

disp[n, θ, ω]/.exampleRule /. freqRule

values = Solve[Det[(dMatrix /.exampleRule /. freqRule ) ] == 0, n]

(eqs  =Thread[(dMatrix /.exampleRule /. freqRule ).{ex,ey,ez} == {0,0,0}]) // TableForm

Solve[eqs[[1]] , {ex}]

Solve[eqs[[2]]  /. values[[2]], {ex}]

eqs[[3]]  /. values[[1]]

Eigenvectors[(dMatrix /.exampleRule /. freqRule )/. values[[1]] ] // Chop

Eigenvectors[(dMatrix /.exampleRule /. freqRule )/. values[[2]] ] // Chop

Example 2

freqRule = { Ωpe -> 0.5, Ωce -> 1}

exampleRule = { ω -> 3 Ωce , θ -> 0 Degree}

(dMatrix /.exampleRule /. freqRule ) // MatrixForm

Det[(dMatrix /.exampleRule /. freqRule )]

disp[n, θ, ω]/.exampleRule /. freqRule

values = Solve[Det[(dMatrix /.exampleRule /. freqRule ) ] == 0, n]

(eqs  =Thread[(dMatrix /.exampleRule /. freqRule ).{ex,ey,ez} == {0,0,0}]) // TableForm

Solve[eqs[[1]]  /. values[[1]], {ex}]

Solve[eqs[[2]]  /. values[[2]], {ex}]

eqs[[3]]

Eigenvectors[(dMatrix /.exampleRule /. freqRule )/. values[[1]] ] // Chop

Eigenvectors[(dMatrix /.exampleRule /. freqRule )/. values[[2]] ] // Chop

Summary

Magnetized plasma have several characteristic frequencies: 
	(i)  the plasma frequency, Ωpe
	(ii) the electron cyclotron frequency, Ωce
	(iii) the ion cyclotron frequency, Ωce/ionMassRatio
	(iv) the ion plasma frequency, Ωpe/√ionMassRatio
Additionally, the plasma conductivity is gryotropic about the direction of the magnetic field.

The variety of frequencies and the anisotropy of the plasma medium makes for a large variety of wave types that depend upon (i) wave frequency, (ii) propagation direction, and (iii) plasma parameters.