Blasius Boundary Layer

APPH 4200 Physics of Fluids
Columbia University

Similarity Equation

eq = f[η] D[f[η], {η, 2}]/2 + D[f[η], {η, 3}] == 0

ηBig = 25.0;

bc = {f'[ηBig] == 1, f[0] == 0, f'[0] == 0}

Finding the Solution

sol = NDSolve[{eq} ~Join~ bc, f, {η, 0, ηBig}]

Graph the Solution

fBlasius = f /. First[sol]

gBlasius[η_] = D[fBlasius[η], η]

Plot[fBlasius[η], {η, 0, ηBig}, PlotLabel -> "f[η]"]

Plot[gBlasius[η], {η, 0, ηBig/2}, PlotLabel -> "g[η]", PlotRange -> All, AxesLabel -> {"η", "u/(Subscript[U, ∞])"}]

Cross Velocity

Normalized to the (Sqrt[Re])…

uy[η_] = (1/2) (η gBlasius[η] - fBlasius[η])

Plot[uy[η], {η, 0, ηBig/2}, PlotLabel -> "Normalized (Subscript[u, y])[η]", PlotRange -> All, AxesLabel -> {"η", "((Subscript[u, y])/(Subscript[U, ∞])) (Sqrt[Re])"}]

Normalized Shear Stress

At the plate surface…

D[gBlasius[η], η] /. η -> 0

Summary

Blasius provided the mathematically rigorous "similiarity" solution to the boundary layer thickness for uniform flow along a fixed plate. The similiarity transformation creates an nonlinear ordinary differential equation that can be easily integrated.