Asteroid Resonances

AP1603

Introduction

About 200 years ago, an interesting relationship was noticed between the distances of successive planets. The distance (in A.U.) between the Nth planet and the Sun is given by the approximate formula:
	(Subscript[R, N]) = 0.4 + 2 ((Subscript[R, N-1])- 0.4)
For example, initializing the sequence with Mercury = 0.4 and Venus = 0.7, then Earth (N = 3) has a radius (Subscript[R, 3])= 1.0.

We can define this sequence as...

rp[1] = 0.4;
rp[2] = 0.7;
rp[n_Integer] = 0.4 + 2 (rp[n - 1] - 0.4);

Table[rp[n], {n, 1,10}]

One consequence of this series was noticed in about 1800. Perhaps there is a planet at (Subscript[R, 5])=2.8. Indeed, this is the location of the asteroid belts; however, it took some time for astronomers to understand this.

I am not sure whether or not the spacing of the planets are well understood, but there is reasonably good understanding of the spacing of the rings of Saturn and the belts of asteroids located at about 2.8 A.U.
For Saturn's rings, the resonant interaction of Saturn's moons destabilize particular orbits of dust and ice comprising the rings. For the asteroid belts, the resonant interation between the gravitational force of Jupiter destabilizes particular orbits of asteroids.

In this notebook, I have constructed a relatively simple model for the interaction between the orbiting planet Jupiter and an asteroid located at a particular circular orbit from the Sun.

The key simplifications used in the following calculations are (1) assume the asteroids remain in circular orbits, and (2) create an approximate model for the integrated torque applied by Jupiter to an asteroid along one complete orbit of the asteroid.

As seen in other notebooks, use of the computer allows investigation of the long-time evolution of very complex (and nonlinear) dynamical interations. For the asteroids with resonant orbits, Jupiter effectively scatters these asteroids into different orbits.

Orbital Resonances

Kepler tells us that a planet's orbital frequency is inversely proportional to the planet's distance from the the Sun, raised to the 3/2 power.

omega[a_] := 2 π /a^(3/2)

Plot[((omega[a])/(2 π)),{a,1,6}]

Plot[((omega[a])/(omega[5.2])),{a,2,5},GridLines->Automatic,PlotRange->{0,4}]

FindRoot[omega[a]/omega[5.2]==3, {a, 2.5}]

FindRoot[omega[a]/omega[5.2]==5/2, {a, 3.0}]

FindRoot[omega[a]/omega[5.2]==7/3, {a, 3.0}]

FindRoot[omega[a]/omega[5.2]==2, {a, 3.2}]

Jupiter's Torque

Some definitions for Jupiter's orbit

aj = 5.20;
wj = 2π/aj^(3/2);
massJS= 1/1048.;

The location of the asteroid, ra, and Jupiter, rj...

ra = {a Cos[omega[a]t],a Sin[omega[a] t],0};
rj = {aj Cos[wj t + ϕ], aj Sin[wj t + ϕ], 0};

dr = rj - ra;

The force on the asteroid from Jupiter...

fj = - 4 (π^2)massJS  dr/(dr . dr)^(3/2);

torque = {0,0,1}.(ra \[Cross] fj);

As Jupiter orbits the Sun, the torque changes...

Plot[Evaluate[Table[torque/.a->2.5,{ϕ,0,π,(π/4)}]],{t,0,((2 π)/(omega[2.5]))}]

These torques are small, but important for "resonant" aseteroids after a long,long time. For resonant asteroids, the net torques add up. To make progess, we need to simplify the calculations.

An Approximate "Net Torque" once around the orbit...

Assuming the orbit remains circular, the net torque is approximately the integral around a complete asteroid orbit.

netTorque[r_,p_] := NIntegrate[N[2π torque/omega[r] /. a -> r /. ϕ -> p], {t, 0, 2π/omega[r]}]

netTorque[2.5,0.0]
netTorque[2.5,45.0 Degree]

Plot[{netTorque[a,0.],((0.25 (((aj-3.5))^4))/(((aj-a))^4))},{a,2.5,3.5},PlotRange->{0,0.25}]

Plot[netTorque[a,(π/2)],{a,2.5,3.5}]

Plot[{netTorque[2.2,p],netTorque[2.3,p],netTorque[2.6,p],netTorque[3.0,p],netTorque[3.6,p]},{p,0.,2. π}, PlotRange -> All]

As least for asteroids closer to Jupiter, the net torque varies with the initial phase like Cos[θ]^3.

Plot[{((Cos[t - π (a-2.1)/(4.5-2.1)])^3) /. a-> 2.2,((Cos[t - π (a-2.1)/(4.5-2.1)])^3) /. a-> 2.6,((Cos[t - π (a-2.1)/(4.5-2.1)])^3) /. a-> 3.6},{t,0,2 π}]

A Mapping

This approximation is the key that allows rapid computational steps...

advance[{p_,r_}]:= Module[{la,lb,rb,tb,netTor,δp},
la = 2 π Sqrt[r]; (* angular momentum on input *)
δp = - π (r-2.1)/(4.5-2.1);
netTor = Cos[p+δp]^3 * 0.25*(aj-3.5)^4/(aj-r)^4;
lb = la + netTor; (* new angular momentum *)
rb = (lb/2/π)^2; (* new radius *)
tb = rb^(3/2); (* new orbital period *)
{Mod[p + tb wj,2π],rb}]

advance[{p, r}] computes the phase of the asteroid's orbit with respect to Jupiter and the orbital radius (in A.U.) around the sun. It assumes the asteroid remains in an exactly circular orbit (which is obviously not true). As the asteroid slows or speeds up due to the net torque from Jupiter, the asteroid simply moves to a larger or smaller orbital radius around the sun.

advance[{0.0,3.0}]

Plots of asteroid resonances

The phase-evolutions of particular asteroids reveal interesting behaviors.

ast1 = NestList[advance,{0.0, 2.95},1000];

p1=ListPlot[ast1,PlotStyle->Red]

ast2 = NestList[advance,{0.0, 2.5},1000];

p2=ListPlot[ast2,PlotStyle->Green]

ast3 = NestList[advance,{0.0, 3.27},1000];

p3=ListPlot[ast3,PlotStyle->Blue]

Show[p1,p2,p3, PlotRange -> {All, {2.4,3.4}}]

A Phase Map

(asteroids = Table[NestList[advance,{Pi/2, a},500],{a,2.2,3.8,0.025}] // Flatten[#,1]&;) // Timing

ListPlot[asteroids,PlotStyle->PointSize[0.005]]

Dimensions[asteroids]

Asteroid Statistics

We can form an approximate "probability distribution function" from the orbit histroies. The likelihood that an asteroid might be found at a particular radius is estimated from a large number of asteroid positions.

asteroidsR = Map[Last,asteroids];

?BinCounts

prob = BinCounts[asteroidsR,{2.0,3.6,0.005}];

ListPlot[prob,Joined->True,Frame->True,RotateLabel->False,FrameLabel->{"Radius Bin","Count"}]

modelPlot = ListPlot[Transpose[{Table[r, {r, 2.0025, 3.6, 0.005}],prob}],Joined->True,Frame->True,RotateLabel->False,FrameLabel->{"Radius (A.U.)","Count"}]

Summary

In this notebook, we derived an approximate expression for the torque applied to an object due to the gravitational attraction of Jupiter. Then, we integrated this torque over an orbit to estimate the gain or loss of angular momentum of the (smaller) orbiting object.
For orbits that resonate with the orbit of Jupiter, these small changes of angular momentum accummulate over time. The object begins to slow down (move out) or speed up (move in) because the changes in velocity add up each orbit. For non-resonate objects, the motion does not change much on average. Sometimes these non-resonant  objects speed up, sometimes they slow down, and on average they the orbits simply don't change much.
For the resonant orbits, the motion becomes chaotic. This means the orbital phase of the object with respect to Jupiter's orbital position becomes un-predictable. We computed phase-plots, and we constructed profiles of the distributions of the asteroid's positions. These resemble the observed banding of the asteroid belts.