Chaotic Tumbling of Hyperion

APAM1601
Columbia University

Hyperion (A tumbling moon of Saturn)

Voyager 1 took this photo of Saturn on Nov. 16, 1980 from a distance of 5.3 million km.

Saturn and its ring system is one of the most unique objects in the sky. When viewed through a modern telescope, the planet appears as a light yellow and gray banded oblate spheroid. Like the other giant planets--Jupiter, Uranus, and Neptune--the visible planet is the cloud top of an extensive gaseous atmosphere.
Saturn orbits the Sun every 29.4577 years; it's orbit has an eccentricity of 0.0556; Saturn's mass is 95.147 times the Earth's; and it rotates rapidly, once every 10.657 hours.
Saturn's white rings were first seen by Galileo Galilei in 1610; his small, imperfect telescope showed the planetary disk flanked by what he first interpreted as being two smaller bodies. Christiaan Huygens correctly theorized (late 1650s) the ring nature of these alleged "companions." James Clerk Maxwell mathematically demonstrated (1857) that the rings were composed of many small, unconnected particles, each orbiting near Saturn's equatorial plane.
The classical designations for the rings are based on the gross ring components identified from the ground, but the Voyager spacecraft have shown the ring system to be highly structured. The radial particle-density distribution changes over distances of hundreds of meters, but individual particles, whose estimated sizes range from tens to hundreds of centimeters, have not been resolved. The ring plane has a maximum thickness of 1 to 2 km (0.6 to 1.2 mi). Spectroscopy shows the presence of water ice, which probably covers rocky silicate cores. The dynamics of the rings are not presently well understood. The theory of satellite resonances predicts that particles whose orbital periods are integral fractions (such as 1/2 or 2/3) of the periods of the satellites become either locked into or perturbed out of a particular orbit, but only a few of the observed gaps can be explained in this manner.

Voyager 2 obtained this picture of Hyperion from a distance of 500,000 km on Aug. 24, 1981.

Cassini took this picture from a distance of 291,000 km on June 28, 2006, and was "image-enhanced" to highlight the surface structures.

Saturn has the most extensive satellite system in the solar system. Not counting the myriad ring particles, more than 20 bodies orbiting around Saturn have so far been identified. Six can be easily seen through the telescope.
Titan is the largest Saturnian satellite and, among all solar-system satellites, is second in size only to the Jovian satellite Ganymede. It is the only satellite with a substantial atmosphere. (Neptune's Triton has a much thinner one.)  With the exception of Phoebe, Iapetus, and Hyperion, they are in nearly circular orbits. You will see, Hyperion's elliptical orbit has a profound effect on its rotational dynamics. All of Saturn's satellites, with the exception of Enceladus, have highly cratered, old surfaces.
Hyperion is relatively small, irregular in shape, and heavily cratered. The long axis is not oriented toward the planet, and this indicates the Hyperion is dynamically unstable. Indeed, Hyperion is one of the finest examples of orbital chaos in the solar system.
Hyperion has a mass which is 20 billion times smaller than Saturn's and about 52,000 times smaller than Earth. Its eccentricity is 0.11; it rotates once around Saturn in 21.3 days; and it is 0.01 A.U. (about 3.8 times farther than the distance between the Earth's moon and Earth).

Introduction

We must describe (1) the equations of motion for the center of mass of Hyperion, and (2) the dynamical equation for the internal rotation and orientation of Hyperion. The center-of-mass motion is the familar Newtonian planetary motion. The rotational motion is determined by the torque applied by Saturn's gravitational field to the asymmertic moon, and the moon's moment of inerta.

For our "dumbell" model of Hyperion, the torque is given by the vector formula:

T = z·((Subscript[r, 1])×(Subscript[F, 1]) + (Subscript[r, 2])×(Subscript[F, 2]))

where (Subscript[r, 1])and (Subscript[r, 2])are the positions of the two masses of the dumbell and (Subscript[F, 1])and (Subscript[F, 2])are the respective gravitational attractions to the planet Saturn. Once the torque is known, the equation of motion for Hyperion's angular rotation is simply

θ'[t] = ω[t]
		ω'[t] = T/I

where I is the moment of inertia. If the dumbell consists of two equal masses separated by 2d, then

I = 2m (d^2)

Equation of Motion for Center of Mass

Since the separation between the two dumbell masses is small, the equations of motion for Hyperion's center-of-mass (COM) orbit about Saturn are identical to the motion of planets about the Sun. Below, we normalize time to the mean period of orbit (21 days) and distance to the mean separation between the center of Saturn and the COM of Hyperion (0.01 AU).

pCOM = {x[t], y[t], vx[t], vy[t]};

dpCOM = {vx[t], vy[t],
-4 (π^2) x[t]/r^3, -4 (π^2) y[t]/r^3}/.  r-> Sqrt[x[t]^2 + y[t]^2]

p0COM = {x0, y0,vx0, vy0};

Equation of Motion for Rotation

Hyperion's rate of change of angular rotation is determined by the torque applied by Saturn.

Some simple vector algebra

a = {ax,ay,az};
b = {bx, by, bz};

a \[Cross] b

a . b

The torque

Let "d" be the distance from the COM to one of the two masses.

r1 = {d Cos[θ[t]], d Sin[θ[t]],0};
r2 =  {d Cos[θ[t]+Pi], d Sin[θ[t]+Pi],0};
rCOM = {x[t],y[t],0};

f1 = -4(π^2) m(r1 + rCOM)/((r1 + rCOM).(r1 + rCOM) )^(3/2)

f2= -4(π^2) m(r2 + rCOM)/((r2 + rCOM).(r2 + rCOM) )^(3/2)

torque = r1 \[Cross] f1 + r2 \[Cross] f2 // Simplify

Let's consider only the case where "d" is very small...

Series[torque[[3]],{d,0,2}] // Simplify

We see the leading order term is proportional to (d^2).

The Leading-Order Expression for Rotational Dynamics

moment = 2 m (d^2); (* Moment of Inertial *)
pROT = {θ[t],ω[t]};
dpROT = {ω[t],
		-(24 m (d^2)(π^2) (Sin[θ[t]] x[t]-Cos[θ[t]] y[t]) (Cos[θ[t]] x[t]+Sin[θ[t]] y[t]))/(((((x[t])^2)+((y[t])^2)))^(5/2))/moment};
p0ROT = {θ0, ω0};

Combined Equations of Motion

p = pCOM ~ Join ~ pROT;
p0 = p0COM ~ Join ~ p0ROT;
dp = dpCOM ~ Join ~ dpROT;

(Thread[...] is an easy way of writing a single equation for a list of variables.)

eqs = Thread[D[p,t] == dp]~ Join ~Thread[{x[0], y[0], vx[0], vy[0], θ[0],ω[0]} == p0]

Numerical Solutions

In this section, the dynamics of Hyperion's internal rotation is examined for circular orbits (which does not represent Hyperion) and elliptical orbits (which shows rotational chaos.)

A Circular Orbit

h1 = NDSolve[eqs /.x0 -> 1 /. y0 -> 0 /. vy0->2 π/. vx0 -> 0/.θ0 -> 0 /. ω0 -> 1, p, {t, 0,10}]//Flatten

Graphical Analysis

ParametricPlot[Evaluate[{x[t],y[t]}/.h1],{t,0,10},AspectRatio->Automatic]

Plot[Mod[Evaluate[θ[t]/.h1],2 π],{t,0,10}]

Plot[Evaluate[ω[t]/.h1],{t,0,10}]

Below, we plot of the angle of the dumbell with respect to the radial. (The ArcTangent is the angle the moon makes to the center of Saturn, and this changes with time as the moon orbits.)

Plot[Mod[Evaluate[θ[t]-ArcTan[x[t],y[t]]/.h1],2 π],{t,0,10}]

Plot[Mod[Evaluate[θ[t]-ArcTan[x[t],y[t]]/.h1]+π,2 π],{t,0,10},PlotLabel->"Radial Orientation of Hyperon",PlotRange->{0,2 π}]

Animation

dsize = 0.1;

hyper[tt_, hRule_] := Module[{δx1, δy1,δx2, δy2},
{δx1, δy1} = ({x[t],y[t]} + dsize {Cos[θ[t]],Sin[θ[t]]})/. hRule /. t-> tt;
{δx2, δy2} = ({x[t],y[t]} + dsize {Cos[θ[t]+π],Sin[θ[t]+π]})/. hRule /. t-> tt;{Disk[{δx1, δy1},dsize/2],Disk[{δx2, δy2} ,dsize/2],Thickness[0.01],Line[{{δx1, δy1},{δx2, δy2}}]} ]

Show[Graphics[{Disk[{0,0},dsize],hyper[1,h1]}],PlotRange->{{-1.1,1.1},{-1.1,1.1}},AspectRatio->Automatic]

Animate[Show[Graphics[{Disk[{0,0},dsize],hyper[t,h1],Text[ToString[t],{-1.,1.},{-1,0}]}],PlotRange->{{-1.1,1.1},{-1.1,1.1}},AspectRatio->Automatic], {t, 0, 2}]

Phase-Space

The orientation of the long axis of Hyperion is an important quantity. When the long axis points to Saturn, the moon is stable. A phase-plot can be made to determine (1) the orientation of Hyperion's axis, and (2) how quickly the axis is changing as a function of time.

phaseTable = Table[Evaluate[{Mod[θ[t] -ArcTan[x[t],y[t]], 2π],ω[t]} /. h1], {t, 0, 10, 0.02}]; (* 500 points *)

phasePlot1=ListPlot[phaseTable,PlotLabel->"Circular Orbit",AxesLabel->{"Δθ","ω"},Ticks->{{0,(π/2),π,((3 π)/2),2 π},Automatic}]

For a different initial condition...

h1p=Flatten[NDSolve[eqs/.x0->1/.y0->0/.vy0->2 π/.vx0->0/.θ0->(π/4)/.ω0->1,p,{t,0,10},MaxSteps->2000]];
phaseTable=Table[Evaluate[{Mod[θ[t]-ArcTan[x[t],y[t]],2 π],ω[t]}/.h1p],{t,0,10,0.02`}];
phasePlot2=ListPlot[phaseTable,PlotLabel->"Circular Orbit",AxesLabel->{"Δθ","ω"},Ticks->{{0,(π/2),π,((3 π)/2),2 π},Automatic}]

Show[phasePlot1,phasePlot2]

An Elliptical Orbit

h2 = NDSolve[eqs /.x0 -> 1 /. y0 -> 0 /. vy0->2 π /1.25/. vx0 -> 0/.θ0 -> 0 /. ω0 -> 1, p, {t, 0,10}]//Flatten

Graphical Analysis

ParametricPlot[Evaluate[{x[t],y[t]}/.h2],{t,0,10},AspectRatio->Automatic]

Plot[Mod[Evaluate[θ[t]/.h2],2 π],{t,0,10}]

Plot[Evaluate[ω[t]/.h2],{t,0,10}]

A plot of the angle of the dumbell with respect to the radial.

Plot[Mod[Evaluate[θ[t]-ArcTan[x[t],y[t]]/.h2],2 π],{t,0,10}]

Plot[Mod[Evaluate[θ[t]-ArcTan[x[t],y[t]]/.h2]+π,2 π],{t,0,10},PlotLabel->"Radial Orientation of Hyperon"]

Animation

Animate[Show[Graphics[{Disk[{0,0},dsize],hyper[t,h2],Text[ToString[t],{-1.,1.},{-1,0}]}],PlotRange->{{-1.1,1.1},{-1.1,1.1}},AspectRatio->Automatic], {t, 0, 8}]

Phase-Space

phaseTable = Table[Evaluate[{Mod[θ[t] -ArcTan[x[t],y[t]], 2π],ω[t]} /. h2], {t, 0, 10, 0.02}]; (* 500 points *)

ListPlot[phaseTable,PlotLabel->"Elliptical Orbit",AxesLabel->{"Δθ","ω"},Ticks->{{0,(π/2),π,((3 π)/2),2 π},Automatic}]

Chaotic Motion

Is the motion of Hyperion chaotic? How do we "know" or "measure" whether or not an object's dynamics is chaotic?

One of the most common tests for chaos is the computation of the Lyapunov exponent for the time variation of two trajectories computed with nearly identical initial conditions.

Circular Orbits are Not Chaotic

For example, let's examine the difference between two dynamical trajectories for Hyperion for circular orbit initial conditions.

h1a = NDSolve[eqs /.x0 -> 1 /. y0 -> 0 /. vy0->2 π/. vx0 -> 0/.θ0 -> 0.01 /. ω0 -> 1, p, {t, 0,10}] // Flatten

dt1[t_] = (θ[t] /. h1) -  (θ[t] /. h1a)

Plot[dt1[t],{t,0,10}]

Elliptical Orbits are Chaotic

In the same way, we'll compute the trajectory difference for elliptical orbits.

h2a = NDSolve[eqs /.x0 -> 1 /. y0 -> 0 /. vy0->2 π /1.25/. vx0 -> 0/.θ0 -> 0.01 /. ω0 -> 1, p, {t, 0,10}] // Flatten

dt2[t_] = (θ[t] /. h2) -  (θ[t] /. h2a)

Plot[dt2[t],{t,0,10}]

Plot[Log[10,Abs[dt2[t]]],{t,0,10},PlotLabel->"Evolution of Difference between Points"]

The difference grows exponetially!

Lyapanov Number

Show[%]

Let's find how quickly the difference grows by using the Fit[...] command.

dtTable = Table[{t,Log[Abs[dt2[t]]]}, {t, 0, 5, 0.05}];

gl=ListPlot[Select[dtTable,Last[#1]<0&]]

logFit = Fit[dtTable, {1, t}, t]

The exponetial growth of the separation of the orbits is proportional to the Lyapunov exponent.

gp=Plot[logFit,{t,0,5},PlotStyle->{RGBColor[1,0,0]}]

Show[gl,gp,PlotLabel->"Exponential Fit"]

Summary

We have studied the tumbling orbit of Hyperon. This is an example of coupled oscillators. 
For non-circular orbits, the rocking motion of the moon is coupled to the slowly changing gravitational force as the object moves closer and then farther away from the planet. 
Coupled oscillators can become chaotic. Notice that chaotic motion is not "random". Each solution to the differential equations is "precise" and determined. When a system is chaotic, this means that two solutions that differ by a very slight change of initial conditions have an exponentially growing separation. 
Deterministic chaos is found in many systems of equations and in many physical situations. A common measure of chaos is the Lyapunov exponent. This is the exponential rate of separation between two initially nearby solutions.