Quantum Potentials

AP1601
Columbia University

Introduction

In this notebook, we explore one-dimensional solutions to the time-dependent Schrödinger's equation for a variety of potential functions, V(x).

Recall, in our simplified units (ℏ = m = 1), the wave function is denoted by ψ(x, t), and Schrodinger's equation is 
	I (∂_t) ψ = - (1/2) (∂_x) (∂_x) ψ + V(x) ψ
In this equation, V(x) is the potential energy of the quantum particle at location x. The term -((∂_x) (∂_x) ψ) / 2 is related to the kinetic energy. Formally, the kinetic energy is one half the square of the momentum; and the momentum is related to -I (∂_x) ψ -> k ψ(k). We use the Fourier transform to calculate the probability of the momentum, Conjugate[ψ(k)] ψ(k) = |ψ(k)((|)^2).
As discussed last week, we use the Crank-Nicholson method to time-advance the wave-function. This solves the finite-difference approximation to the continuous partial differential equation with good accuracy. We set the grid-spacing to unity in both the time and spatial directions.

Some aspects of the behavior of our solutions can be anticipated through analogy with classical mechanics. For example, if there exists a potential barrier, V, that is much larger than the kinetic energy, (k^2)/ 2, the particle will reflect from the barrier. Other aspects are surprising. For example, when the barrier is only slightly larger than the kinetic energy, there is a significant probability that the particle will pass through the barrier wall.

Preparing the Notebook

As discussed last week, we use the Crank-Nicholson method to time-advance the wave-function. This solves the finite-difference approximation to the continuous partial differential equation with good accuracy. We set the grid-spacing to unity in both the time and spatial directions.

To further speed the computations and allow solutions to more complex problems, we will pre-define all of the matrices used in the Crank-Nicholson steps. These matrices must be re-defined if the grid size, nGrid, changes.

cnStep[ψ_List, v_List] := Module[{sparseA,r,len},
len = Length[ψ];
sparseA = SparseArray[{{i_,i_} :> 1 + I (1.0 + v[[i]]) 0.5, {i_,j_}/; Abs[i-j] ==  1 -> - I 0.25}, {len, len}, 0.0];
r =  ListConvolve[{I 0.25,1.0 - I 0.5, I 0.25},ψ, 2, 0.0] - I ψ v 0.5;
(* fixed boundaries *)
sol = LinearSolve[sparseA,r];
sol]

cnStep[a_List,b_List,v_List][ψ_List] :=  Module[{sparseA,r,len},(* a faster, pre-defined version of cnStep *)
len = Length[ψ];
sparseA = SparseArray[{Band[{1,2}] -> a, Band[{1,1}] -> b, Band[{2,1}] -> a},len];
r =  ListConvolve[{I 0.25,1.0 - I 0.5, I 0.25},ψ, 2, 0.0] - I ψ v 0.5;
LinearSolve[sparseA,r]]

(* apply cnStep multiple times *)cnStep[n_Integer][ψ_List, v_List] := Nest[cnStep[#,v]&, ψ, n];
cnStep[n_Integer,a_List, b_List, v_List][ψ_List] := Nest[cnStep[a,b,v][#]&, ψ, n];

Mathematica allows different functions to be called for different argument patterns:

?cnStep

initial[k_,x0_,s_][x_] := Exp[I k x] Exp[-((x-x0)/(2 s))^2]/Sqrt[ Sqrt[2 π s^2]];

plotψ[ψ_List,options___]:=Module[{p1,p2,p3,p4},p1=ListPlot[Re[ψ],PlotStyle->Blue,Joined->True];p2=ListPlot[Im[ψ],PlotStyle->Red,Joined->True];p3=ListPlot[Abs[ψ],Joined->True];p4=ListPlot[-Abs[ψ],Joined->True];Show[p1,p2,p3,p4,options]]

This week, we ask the question: What happens to the solution when V(x) does not equal zero?

A Parabolic Potential Well

Let's examine a "parabolic" potential well. For a parabolic potential, V(x) = c (x^2), where c is a constant.

nGrid=100;
v=Table[((2 (x^2))/(nGrid^2)),{x,-(nGrid/2)+1,(nGrid/2)}];
a=Table[-I 0.25,{i,1,nGrid-1}];
b=Table[1.0+I (1.0+v[[i]]) 0.5,{i,1,nGrid}];
ListPlot[v]

ψ0 = Table[initial[0.6,nGrid/2,8][x], {x, 1, nGrid}];
plotψ[ψ0]

sol=NestList[cnStep[5,a,b,v][#1]&,ψ0,100];
ListDensityPlot[Abs[sol],Mesh->False,ColorFunction->Hue,PlotRange->All]
ListPlot3D[Abs[sol],PlotRange->All,Mesh->False]

Momentum Probability

As described last week, the wave-function can also be displayed in "momentum space". We require the Fourier transform (along the x direction) of the solution, ψ(x, t) -> ψ(k, t). We use the routines developed in 7-Exercises.nb.

rearrangeFourier[p_List] := Reverse[p[[Range[nGrid/2 + 1, nGrid]]] ~ Join~ p[[Range[1,nGrid/2]]]]

solk = rearrangeFourier[Fourier[#]]& /@ sol;

ListDensityPlot[Abs[solk],Mesh->False,ColorFunction->Hue,PlotRange->All]

ListPlot3D[Abs[solk],PlotRange->All,Mesh->False]

Notice that zero momentum is at position nGrid/2. The particle bounces back and forth. The momentum is greatest when the particle is at the center. This is expected since this is the minimum of the potential energy!

A Linear Potential Well

Let's examine a "linear" potential well.

nGrid=100;
v=Table[((Abs[x])/nGrid),{x,-(nGrid/2)+1,(nGrid/2)}];
a=Table[-I 0.25,{i,1,nGrid-1}];
b=Table[1.0+I (1.0+v[[i]]) 0.5,{i,1,nGrid}];
ListPlot[v]

ψ0 = Table[initial[0.6,nGrid/2,8][x], {x, 1, nGrid}];
plotψ[ψ0]

sol=NestList[cnStep[5,a,b,v][#1]&,ψ0,100];
ListDensityPlot[Abs[sol],Mesh->False,ColorFunction->Hue,PlotRange->All]
ListPlot3D[Abs[sol],PlotRange->All,Mesh->False]

Momentum Probability

solk = rearrangeFourier[Fourier[#]]& /@ sol;

ListDensityPlot[Abs[solk],Mesh->False,ColorFunction->Hue,PlotRange->All]

ListPlot3D[Abs[solk],PlotRange->All,Mesh->False]

Potential Barriers (1)

Let's examine a small, positive potential barrier.

nGrid=200;
v=Table[If[-3≤x≤3,0.2,0.0],{x,-(nGrid/2)+1,(nGrid/2)}];
a=Table[-I 0.25,{i,1,nGrid-1}];
b=Table[1.0+I (1.0+v[[i]]) 0.5,{i,1,nGrid}];
ListPlot[v]

ψ0 = Table[initial[0.6,nGrid/4,8][x], {x, 1, nGrid}];
plotψ[ψ0, PlotRange-> All]

sol=NestList[cnStep[5,a,b,v][#1]&,ψ0,100];
ListDensityPlot[Abs[sol],Mesh->False,ColorFunction->Hue,PlotRange->All]
ListPlot3D[Abs[sol],PlotRange->All,Mesh->False]

Momentum Probability

solk = rearrangeFourier[Fourier[#]]& /@ sol;

ListDensityPlot[Abs[solk],Mesh->False,ColorFunction->Hue,PlotRange->All]
ListDensityPlot[Abs[solk],Mesh->False,ColorFunction->Hue,PlotRange->All, DataRange -> {2 π/200 {-100,100},{0,5 100}}, FrameLabel -> {"k","time"}]

Potential Barriers (2)

Let's examine a negative potential barrier.

nGrid=200;
v=Table[If[-10≤x≤10,-1.0,0.0],{x,-(nGrid/2)+1,(nGrid/2)}];
a=Table[-I 0.25,{i,1,nGrid-1}];
b=Table[1.0+I (1.0+v[[i]]) 0.5,{i,1,nGrid}];
ListPlot[v]

ψ0 = Table[initial[0.6,nGrid/4,8][x], {x, 1, nGrid}];
plotψ[ψ0, PlotRange-> All]

sol=NestList[cnStep[5,a,b,v][#1]&,ψ0,100];
ListDensityPlot[Abs[sol],Mesh->False,ColorFunction->Hue,PlotRange->All]
ListPlot3D[Abs[sol],PlotRange->All,Mesh->False]

Momentum Probability

solk = rearrangeFourier[Fourier[#]]& /@ sol;

ListDensityPlot[Abs[solk],Mesh->False,ColorFunction->Hue,PlotRange->All]

Potential Barriers (3)

Let's examine a particle trapped inside a barrier.

nGrid=200;
v=Table[If[-25≤x≤25,-0.5,0.0],{x,-(nGrid/2)+1,(nGrid/2)}];
a=Table[-I 0.25,{i,1,nGrid-1}];
b=Table[1.0+I (1.0+v[[i]]) 0.5,{i,1,nGrid}];
ListPlot[v]

Initially, we start with a very low initial momentum, p0 = 0.02.

ψ0 = Table[initial[0.02,nGrid/2,8][x], {x, 1, nGrid}];
plotψ[ψ0, PlotRange-> All]

sol=NestList[cnStep[5,a,b,v][#1]&,ψ0,100];
ListDensityPlot[Abs[sol],Mesh->False,ColorFunction->Hue,PlotRange->All]
ListPlot3D[Abs[sol],PlotRange->All,Mesh->False]

Momentum Probability

solk = rearrangeFourier[Fourier[#]]& /@ sol;

ListDensityPlot[Abs[solk],Mesh->False,ColorFunction->Hue,PlotRange->All]

Try increasing the kinetic energy of the particle by increasing the initial momentum. What happens when p0 -> 1.0, so that (k^2)/ 2 ~ δV?

Summary

We have solved the time-dependent Schrödinger's equations with a several simple potential wells.

For parabolic and linear potential wells, we found solutions that both resemble and contrast with their classical counter-parts. For parabolic wells, small wave packets oscillate periodically. For the "linear" potential well, the wave-function reflects in a complex way, generating a quantum interference pattern. 
Potential barriers cause reflection of the wave function. Surprisingly, potential wells also cause reflections. For initial conditions when the particle's energy is trapped within the potential well, particles can be confined. However, as the particle's momentum nears the depth of the confining potential, the particle escapes.